mirror of
https://github.com/outbackdingo/terraform-render-bootstrap.git
synced 2026-01-27 10:20:45 +00:00
a54fe54d98
* By default the `networking` CNI provider is pre-installed, but the component variable provides an extensible mechanism to skip installing these components * Validate that networking can only be set to one of flannel, calico, or cilium
60 lines
2.6 KiB
HCL
60 lines
2.6 KiB
HCL
# Assets generated only when certain options are chosen
|
|
|
|
locals {
|
|
# flannel manifests map
|
|
# { manifests-networking/manifest.yaml => content }
|
|
flannel_manifests = {
|
|
for name in fileset("${path.module}/resources/flannel", "*.yaml") :
|
|
"manifests/network/${name}" => templatefile(
|
|
"${path.module}/resources/flannel/${name}",
|
|
{
|
|
flannel_image = var.container_images["flannel"]
|
|
flannel_cni_image = var.container_images["flannel_cni"]
|
|
pod_cidr = var.pod_cidr
|
|
daemonset_tolerations = var.daemonset_tolerations
|
|
}
|
|
)
|
|
if var.components.enable && var.components.flannel.enable && var.networking == "flannel"
|
|
}
|
|
|
|
# calico manifests map
|
|
# { manifests-networking/manifest.yaml => content }
|
|
calico_manifests = {
|
|
for name in fileset("${path.module}/resources/calico", "*.yaml") :
|
|
"manifests/network/${name}" => templatefile(
|
|
"${path.module}/resources/calico/${name}",
|
|
{
|
|
calico_image = var.container_images["calico"]
|
|
calico_cni_image = var.container_images["calico_cni"]
|
|
network_mtu = var.network_mtu
|
|
network_encapsulation = indent(2, var.network_encapsulation == "vxlan" ? "vxlanMode: Always" : "ipipMode: Always")
|
|
ipip_enabled = var.network_encapsulation == "ipip" ? true : false
|
|
ipip_readiness = var.network_encapsulation == "ipip" ? indent(16, "- --bird-ready") : ""
|
|
vxlan_enabled = var.network_encapsulation == "vxlan" ? true : false
|
|
network_ip_autodetection_method = var.network_ip_autodetection_method
|
|
pod_cidr = var.pod_cidr
|
|
enable_reporting = var.enable_reporting
|
|
daemonset_tolerations = var.daemonset_tolerations
|
|
}
|
|
)
|
|
if var.components.enable && var.components.calico.enable && var.networking == "calico"
|
|
}
|
|
|
|
# cilium manifests map
|
|
# { manifests-networking/manifest.yaml => content }
|
|
cilium_manifests = {
|
|
for name in fileset("${path.module}/resources/cilium", "**/*.yaml") :
|
|
"manifests/network/${name}" => templatefile(
|
|
"${path.module}/resources/cilium/${name}",
|
|
{
|
|
cilium_agent_image = var.container_images["cilium_agent"]
|
|
cilium_operator_image = var.container_images["cilium_operator"]
|
|
pod_cidr = var.pod_cidr
|
|
daemonset_tolerations = var.daemonset_tolerations
|
|
}
|
|
)
|
|
if var.components.enable && var.components.cilium.enable && var.networking == "cilium"
|
|
}
|
|
}
|
|
|