mirror of
https://github.com/Telecominfraproject/OpenCellular.git
synced 2025-12-31 11:01:19 +00:00
8a16e6483a
Until HOOK_INIT has completed, do not allow any tasks other than HOOKS or IDLE to be scheduled. Programmers often make the assumption that a HOOK_INIT function is guaranteed to be run before task code that depends on it, so let's make it so. BUG=chromium:649398 BRANCH=None TEST=Manual on kevin, compare boot without patch: ... [0.004 power state 0 = G3, in 0x0008] <-- from chipset task RTC: 0x00000000 (0.00 s) [0.004 power state 4 = G3->S5, in 0x0008] RTC: 0x00000000 (0.00 s) [0.005 clear MKBP fifo] [0.006 clear MKBP fifo] [0.006 KB init state: ... <-- from keyscan task [0.012 SW 0x05] [0.155 hash start 0x00020000 0x00019a38] [0.158 HOOK_INIT DONE!] ... to boot with patch: ... RTC: 0x58cc614c (1489789260.00 s) [0.004 clear MKBP fifo] [0.005 clear MKBP fifo] [0.010 SW 0x05] [0.155 hash start 0x00020000 0x000198e0] [0.157 HOOK_INIT DONE!] ... Also, verify kevin boots to OS and is generally functional through sysjump and basic tasks, and verify elm (stm32f0 / cortex-m0) boots. Change-Id: If56fab05ce9b9650feb93c5cfc2d084aa281e622 Signed-off-by: Shawn Nematbakhsh <shawnn@chromium.org> Reviewed-on: https://chromium-review.googlesource.com/456628 Commit-Ready: Shawn N <shawnn@chromium.org> Tested-by: Shawn N <shawnn@chromium.org> Reviewed-by: Vincent Palatin <vpalatin@chromium.org>
82 lines
2.8 KiB
ArmAsm
82 lines
2.8 KiB
ArmAsm
/* Copyright (c) 2014 The Chromium OS Authors. All rights reserved.
|
|
* Use of this source code is governed by a BSD-style license that can be
|
|
* found in the LICENSE file.
|
|
*
|
|
* Context swtching
|
|
*/
|
|
|
|
#include "config.h"
|
|
|
|
.text
|
|
|
|
.syntax unified
|
|
.code 16
|
|
|
|
/**
|
|
* Task context switching
|
|
*
|
|
* Change the task scheduled after returning from the exception.
|
|
*
|
|
* Save the registers of the current task below the exception context on
|
|
* its task, then restore the live registers of the next task and set the
|
|
* process stack pointer to the new stack.
|
|
*
|
|
* r0: pointer to the task to switch from
|
|
* r1: pointer to the task to switch to
|
|
*
|
|
* must be called from interrupt context
|
|
*
|
|
* the structure of the saved context on the stack is :
|
|
* r8, r9, r10, r11, r4, r5, r6, r7, r0, r1, r2, r3, r12, lr, pc, psr
|
|
* additional registers <|> exception frame
|
|
*/
|
|
.global __switchto
|
|
.thumb_func
|
|
__switchto:
|
|
mrs r2, psp @ get the task stack where the context has been saved
|
|
mov r3, sp
|
|
mov sp, r2
|
|
push {r4-r7} @ save additional r4-r7 in the task stack
|
|
mov r4, r8
|
|
mov r5, r9
|
|
mov r6, r10
|
|
mov r7, r11
|
|
push {r4-r7} @ save additional r8-r11 in the task stack
|
|
mov r2, sp @ prepare to save former task stack pointer
|
|
mov sp, r3 @ restore system stack pointer
|
|
str r2, [r0] @ save the task stack pointer in its context
|
|
ldr r2, [r1] @ get the new scheduled task stack pointer
|
|
ldmia r2!, {r4-r7} @ restore r8-r11 for the next task context
|
|
mov r8, r4
|
|
mov r9, r5
|
|
mov r10, r6
|
|
mov r11, r7
|
|
ldmia r2!, {r4-r7} @ restore r4-r7 for the next task context
|
|
msr psp, r2 @ set the process stack pointer to exception context
|
|
bx lr @ return from exception
|
|
|
|
/**
|
|
* Start the task scheduling. r0 is a pointer to task_stack_ready, which is
|
|
* set to 1 after the task stack is set up.
|
|
*/
|
|
.global __task_start
|
|
.thumb_func
|
|
__task_start:
|
|
ldr r2,=scratchpad @ area used as dummy thread stack for the first switch
|
|
movs r3, #2 @ use : priv. mode / thread stack / no floating point
|
|
adds r2, #17*4 @ put the pointer at the top of the stack
|
|
movs r1, #0 @ __Schedule parameter : re-schedule nothing
|
|
msr psp, r2 @ setup a thread stack up to the first context switch
|
|
movs r2, #1 @ r2 = TASK_SCHEDULER_INIT
|
|
isb @ ensure the write is done
|
|
msr control, r3
|
|
movs r3, r0
|
|
movs r0, #0 @ __Schedule parameter : de-schedule nothing
|
|
isb @ ensure the write is done
|
|
str r2, [r3] @ Task scheduling is now active
|
|
bl __schedule @ execute the task with the highest priority
|
|
/* we should never return here */
|
|
movs r0, #1 @ set to EC_ERROR_UNKNOWN
|
|
bx lr
|
|
|