mirror of
https://github.com/Telecominfraproject/OpenCellular.git
synced 2026-01-08 00:21:46 +00:00
a94e3277b3
Add build information (date/time/builder) which can be displayed at the EC console. Generate a version from the board name and the branch tag. Signed-off-by: Vincent Palatin <vpalatin@chromium.org> BUG=chromium-os:27013 TEST=on BDS, run version command on the console. inspect the built binary. Change-Id: Idb1f68898ba6b811d02919f17ab4536ed9f8934a
71 lines
1.6 KiB
ArmAsm
71 lines
1.6 KiB
ArmAsm
/* Copyright (c) 2012 The Chromium OS Authors. All rights reserved.
|
|
* Use of this source code is governed by a BSD-style license that can be
|
|
* found in the LICENSE file.
|
|
*/
|
|
#include "config.h"
|
|
|
|
#define CONFIG_FW_SECT_OFF(section) CONFIG_FW_##section##_OFF
|
|
#define CONFIG_FW_BASE(section) (CONFIG_FLASH_BASE + CONFIG_FW_SECT_OFF(section))
|
|
|
|
OUTPUT_FORMAT("elf32-littlearm", "elf32-littlearm", "elf32-littlearm")
|
|
OUTPUT_ARCH(arm)
|
|
ENTRY(reset)
|
|
MEMORY
|
|
{
|
|
FLASH (rx) : ORIGIN = CONFIG_FW_BASE(SECTION), LENGTH = CONFIG_FW_IMAGE_SIZE
|
|
IRAM (rw) : ORIGIN = CONFIG_RAM_BASE, LENGTH = CONFIG_RAM_SIZE
|
|
}
|
|
SECTIONS
|
|
{
|
|
.text : {
|
|
OUTDIR/core/CORE/init.o (.text.vecttable)
|
|
. = ALIGN(4);
|
|
*(.rodata.ver)
|
|
. = ALIGN(4);
|
|
OUTDIR/core/CORE/init.o (.text)
|
|
*(.text*)
|
|
#ifdef COMPILE_FOR_RAM
|
|
} > IRAM
|
|
#else
|
|
} > FLASH
|
|
#endif
|
|
. = ALIGN(4);
|
|
.rodata : {
|
|
__irqprio = .;
|
|
*(.rodata.irqprio)
|
|
__irqprio_end = .;
|
|
. = ALIGN(4);
|
|
__cmds = .;
|
|
*(.rodata.cmds)
|
|
__cmds_end = .;
|
|
__hcmds = .;
|
|
*(.rodata.hcmds)
|
|
__hcmds_end = .;
|
|
*(.rodata*)
|
|
. = ALIGN(4);
|
|
#ifdef COMPILE_FOR_RAM
|
|
} > IRAM
|
|
__ro_end = . ;
|
|
.data : {
|
|
#else
|
|
} > FLASH
|
|
__ro_end = . ;
|
|
.data : AT(ADDR(.rodata) + SIZEOF(.rodata)) {
|
|
#endif
|
|
. = ALIGN(4);
|
|
__data_start = .;
|
|
*(.data.tasks)
|
|
*(.data)
|
|
. = ALIGN(4);
|
|
__data_end = .;
|
|
} > IRAM
|
|
.bss : {
|
|
. = ALIGN(4);
|
|
__bss_start = .;
|
|
*(.bss)
|
|
. = ALIGN(4);
|
|
__bss_end = .;
|
|
} > IRAM
|
|
/DISCARD/ : { *(.ARM.*) }
|
|
}
|