mirror of
https://github.com/lingble/meta-tegra.git
synced 2025-10-29 11:32:30 +00:00
8660b9d3d0
* The CXX_FOR_CUDA variable is used to set CUDAHOSTCXX * CMAKE_CUDA_ARCHITECTURES support is added Signed-off-by: Matt Madison <matt@madison.systems>
36 lines
981 B
BlitzBasic
36 lines
981 B
BlitzBasic
DESCRIPTION = "SDK environment setup for CUDA targets"
|
|
LICENSE = "MIT"
|
|
LIC_FILES_CHKSUM = "file://${COMMON_LICENSE_DIR}/MIT;md5=0835ade698e0bcf8506ecda2f7b4f302"
|
|
|
|
SRC_URI = "file://cuda_target.sh.in"
|
|
|
|
COMPATIBLE_MACHINE = "(cuda)"
|
|
|
|
inherit cuda-gcc
|
|
|
|
S = "${WORKDIR}"
|
|
|
|
COMPILER_CMD = "${@d.getVar('CXX_FOR_CUDA').split()[0]}"
|
|
|
|
def arch_flags(d):
|
|
archflags = d.getVar('TARGET_CC_ARCH')
|
|
if archflags:
|
|
return "-Xcompiler " + ','.join(archflags.split())
|
|
return ""
|
|
|
|
do_compile() {
|
|
sed -e"s!@CUDA_NVCC_ARCH_FLAGS@!${CUDA_NVCC_ARCH_FLAGS}!" \
|
|
-e"s!@ARCHFLAGS@!${@arch_flags(d)}!" \
|
|
-e"s!@CUDA_ARCHITECTURES@!${CUDA_ARCHITECTURE}!" \
|
|
-e"s!@COMPILER_CMD@!${COMPILER_CMD}!" ${S}/cuda_target.sh.in > ${B}/cuda_target.sh
|
|
}
|
|
|
|
do_install() {
|
|
install -d ${D}/environment-setup.d
|
|
install -m 0644 ${B}/cuda_target.sh ${D}/environment-setup.d/
|
|
}
|
|
|
|
FILES:${PN} = "/environment-setup.d"
|
|
RDEPENDS:${PN} = "tegra-cmake-overrides"
|
|
PACKAGE_ARCH:tegra = "${TEGRA_PKGARCH}"
|