mirror of
https://github.com/lingble/meta-tegra.git
synced 2025-10-29 03:22:36 +00:00
b9507ceb23
* Ran convert-overrides.py to generate the initial changes * Manual cleanup afterwards (which was a lot, due to our extensive use of overrides). Signed-off-by: Matt Madison <matt@madison.systems>
52 lines
2.3 KiB
BlitzBasic
52 lines
2.3 KiB
BlitzBasic
SUMMARY = "VA-API support to GStreamer"
|
|
DESCRIPTION = "gstreamer-vaapi consists of a collection of VA-API \
|
|
based plugins for GStreamer and helper libraries: `vaapidecode', \
|
|
`vaapiconvert', and `vaapisink'."
|
|
|
|
REALPN = "gstreamer-vaapi"
|
|
|
|
LICENSE = "LGPLv2.1+"
|
|
LIC_FILES_CHKSUM = "file://COPYING.LIB;md5=4fbd65380cdd255951079008b364516c"
|
|
|
|
SRC_URI = "https://gstreamer.freedesktop.org/src/${REALPN}/${REALPN}-${PV}.tar.xz \
|
|
file://0001-gst-vaapi-Makefile.am-Add-EGL_CFLAGS-to-libgstvaapi-.patch \
|
|
file://0001-vaapsink-downgrade-to-marginal.patch \
|
|
file://0001-libs-encoder-jpeg-set-component-id-and-Tqi.patch \
|
|
file://0001-libs-decoder-release-VA-buffers-after-vaEndPicture.patch \
|
|
"
|
|
|
|
SRC_URI[md5sum] = "2fae3442f5f23e7354a0c592bc7b9065"
|
|
SRC_URI[sha256sum] = "ce18dbfe961c6a8d31270231686075586bf7a7df62b778c8e7f5ec148251d0a3"
|
|
|
|
S = "${WORKDIR}/${REALPN}-${PV}"
|
|
DEPENDS = "libva gstreamer1.0 gstreamer1.0-plugins-base gstreamer1.0-plugins-bad"
|
|
|
|
inherit autotools pkgconfig gtk-doc features_check upstream-version-is-even
|
|
|
|
REQUIRED_DISTRO_FEATURES ?= "opengl"
|
|
|
|
PACKAGES =+ "${PN}-tests"
|
|
|
|
# OpenGL packageconfig factored out to make it easy for distros
|
|
# and BSP layers to pick either glx, egl, or no GL. By default,
|
|
# try detecting X11 first, and if found (with OpenGL), use GLX,
|
|
# otherwise try to check if EGL can be used.
|
|
PACKAGECONFIG_GL ?= "${@bb.utils.contains('DISTRO_FEATURES', 'x11 opengl', 'glx', \
|
|
bb.utils.contains('DISTRO_FEATURES', 'opengl', 'egl', \
|
|
'', d), d)}"
|
|
|
|
PACKAGECONFIG ??= "drm \
|
|
${PACKAGECONFIG_GL} \
|
|
${@bb.utils.filter('DISTRO_FEATURES', 'wayland x11', d)}"
|
|
|
|
PACKAGECONFIG[drm] = "--enable-drm,--disable-drm,udev libdrm"
|
|
PACKAGECONFIG[egl] = "--enable-egl,--disable-egl,virtual/egl"
|
|
PACKAGECONFIG[glx] = "--enable-glx,--disable-glx,virtual/libgl"
|
|
PACKAGECONFIG[wayland] = "--enable-wayland,--disable-wayland,wayland"
|
|
PACKAGECONFIG[x11] = "--enable-x11,--disable-x11,virtual/libx11 libxrandr libxrender"
|
|
|
|
FILES:${PN} += "${libdir}/gstreamer-*/*.so"
|
|
FILES:${PN}-dbg += "${libdir}/gstreamer-*/.debug"
|
|
FILES:${PN}-dev += "${libdir}/gstreamer-*/*.la ${libdir}/gstreamer-*/*.a"
|
|
FILES:${PN}-tests = "${bindir}/*"
|