mirror of
https://github.com/Telecominfraproject/OpenCellular.git
synced 2026-01-10 17:41:54 +00:00
15854fa680
This simplifies the re-flashing for stm32 based platforms. Signed-off-by: Vincent Palatin <vpalatin@chromium.org> BUG=chrome-os-partner:8865 TEST=On Daisy, flashrom -p internal:bus=lpc -w ec.bin Change-Id: I66860383c34110b1edf852929c244a2b682bc105
144 lines
3.7 KiB
ArmAsm
144 lines
3.7 KiB
ArmAsm
/* Copyright (c) 2012 The Chromium OS Authors. All rights reserved.
|
|
* Use of this source code is governed by a BSD-style license that can be
|
|
* found in the LICENSE file.
|
|
*/
|
|
#include "config.h"
|
|
|
|
#define FW_OFF_(section) CONFIG_FW_##section##_OFF
|
|
#define FW_OFF(section) (CONFIG_FLASH_BASE + FW_OFF_(section))
|
|
|
|
#define FW_SIZE_(section) CONFIG_FW_##section##_SIZE
|
|
#define FW_SIZE(section) FW_SIZE_(section)
|
|
|
|
|
|
OUTPUT_FORMAT("elf32-littlearm", "elf32-littlearm", "elf32-littlearm")
|
|
OUTPUT_ARCH(arm)
|
|
ENTRY(reset)
|
|
MEMORY
|
|
{
|
|
FLASH (rx) : ORIGIN = FW_OFF(SECTION), LENGTH = FW_SIZE(SECTION)
|
|
IRAM (rw) : ORIGIN = CONFIG_RAM_BASE, LENGTH = CONFIG_RAM_SIZE
|
|
}
|
|
SECTIONS
|
|
{
|
|
.text : {
|
|
OUTDIR/core/CORE/init.o (.text.vecttable)
|
|
. = ALIGN(4);
|
|
*(.rodata.ver)
|
|
. = ALIGN(4);
|
|
OUTDIR/core/CORE/init.o (.text)
|
|
*(.text*)
|
|
#ifdef COMPILE_FOR_RAM
|
|
} > IRAM
|
|
#else
|
|
} > FLASH
|
|
#endif
|
|
. = ALIGN(4);
|
|
.rodata : {
|
|
/* Symbols defined here are declared in link_defs.h */
|
|
__irqprio = .;
|
|
*(.rodata.irqprio)
|
|
__irqprio_end = .;
|
|
|
|
. = ALIGN(4);
|
|
__cmds = .;
|
|
*(SORT(.rodata.cmds*))
|
|
__cmds_end = .;
|
|
|
|
. = ALIGN(4);
|
|
__hcmds = .;
|
|
*(.rodata.hcmds)
|
|
__hcmds_end = .;
|
|
|
|
. = ALIGN(4);
|
|
__hooks_init = .;
|
|
*(.rodata.HOOK_INIT)
|
|
__hooks_init_end = .;
|
|
|
|
__hooks_freq_change = .;
|
|
*(.rodata.HOOK_FREQ_CHANGE)
|
|
__hooks_freq_change_end = .;
|
|
|
|
__hooks_sysjump = .;
|
|
*(.rodata.HOOK_SYSJUMP)
|
|
__hooks_sysjump_end = .;
|
|
|
|
__hooks_chipset_startup = .;
|
|
*(.rodata.HOOK_CHIPSET_STARTUP)
|
|
__hooks_chipset_startup_end = .;
|
|
|
|
__hooks_chipset_resume = .;
|
|
*(.rodata.HOOK_CHIPSET_RESUME)
|
|
__hooks_chipset_resume_end = .;
|
|
|
|
__hooks_chipset_suspend = .;
|
|
*(.rodata.HOOK_CHIPSET_SUSPEND)
|
|
__hooks_chipset_suspend_end = .;
|
|
|
|
__hooks_chipset_shutdown = .;
|
|
*(.rodata.HOOK_CHIPSET_SHUTDOWN)
|
|
__hooks_chipset_shutdown_end = .;
|
|
|
|
__hooks_ac_change = .;
|
|
*(.rodata.HOOK_AC_CHANGE)
|
|
__hooks_ac_change_end = .;
|
|
|
|
__hooks_lid_change = .;
|
|
*(.rodata.HOOK_LID_CHANGE)
|
|
__hooks_lid_change_end = .;
|
|
|
|
. = ALIGN(4);
|
|
*(.rodata*)
|
|
|
|
#if defined(SECTION_IS_RO) && defined(CONFIG_FLASH)
|
|
. = ALIGN(64);
|
|
*(.google)
|
|
#endif
|
|
#ifdef COMPILE_FOR_RAM
|
|
} > IRAM
|
|
__ro_end = . ;
|
|
.data : {
|
|
#else
|
|
} > FLASH
|
|
__ro_end = . ;
|
|
.data : AT(ADDR(.rodata) + SIZEOF(.rodata)) {
|
|
#endif
|
|
. = ALIGN(4);
|
|
__data_start = .;
|
|
*(.data.tasks)
|
|
*(.data)
|
|
. = ALIGN(4);
|
|
*(.iram.text)
|
|
. = ALIGN(4);
|
|
__data_end = .;
|
|
} > IRAM
|
|
/* The linker won't notice if the .data section is too big to fit,
|
|
* apparently because we're sending it into IRAM, not FLASH. The following
|
|
* symbol isn't used by the code, but running "objdump -t *.elf | grep hey"
|
|
* will let us check how much flash space we're actually using. The
|
|
* explicit ASSERT afterwards will cause the linker to abort if we use too
|
|
* much. */
|
|
__hey_flash_used = LOADADDR(.data) + SIZEOF(.data) - FW_OFF(SECTION);
|
|
ASSERT(FW_SIZE(SECTION) >
|
|
(LOADADDR(.data) + SIZEOF(.data) - FW_OFF(SECTION)),
|
|
"No room left in the flash")
|
|
#if !(defined(SECTION_IS_RO) && defined(CONFIG_FLASH))
|
|
/DISCARD/ : {
|
|
*(.google)
|
|
}
|
|
#endif
|
|
.bss : {
|
|
. = ALIGN(4);
|
|
__bss_start = .;
|
|
*(.bss)
|
|
. = ALIGN(4);
|
|
__bss_end = .;
|
|
|
|
/* Shared memory buffer must be at the end of preallocated RAM, so it
|
|
* can expand to use all the remaining RAM. */
|
|
__shared_mem_buf = .;
|
|
} > IRAM
|
|
|
|
/DISCARD/ : { *(.ARM.*) }
|
|
}
|